View source for Overloaded operators

{{draft task}}
An [https://en.wikipedia.org/wiki/Operator_overloading overloaded operator] can be used on more than one data type, or represents a different action depending on the context. For example, if your language lets you use "+" for adding numbers and concatenating strings, then one would say that the "+" operator is overloaded.

;Task
Demonstrate overloaded operators in your language, by showing the different types of data they can or cannot operate on, and the results of each operation.

<br><br>

=={{header|6502 Assembly}}==

Many commands have multiple [[6502_Assembly#Addressing_Modes| addressing modes]], which alter the way a command is executed. On the 6502 most of these are in fact different opcodes, using the same mnemonic. 
<lang 6502asm>LDA #$80    ;load the value 0x80 (decimal 128) into the accumulator.
LDA $80     ;load the value stored at zero page memory address $80
LDA $2080   ;load the value stored at absolute memory address $2080.
LDA $80,x   ;load the value stored at memory address ($80+x).
LDA ($80,x) ;use the values stored at $80+x and $81+x as a 16-bit memory address to load from.
LDA ($80),y ;use the values stored at $80 and $81 as a 16-bit memory address to load from. Load from that address + y.</lang>

=={{header|ALGOL 68}}==
This overrides the standard integer + operator (as in the F# sample) and provides an overloaded TOSTRING operator.
Also, the + operator is overloaded to operate on an INT left-hand operand and a BOOL right-hand operand.<br>
Though not shown here, it is also possible to change the priorities of existing dyadic operators.
For new dyadic operators, the priority must be specified (though some implementations provide a default).
In both cases this is done with a PRIO declaration.
<lang algol68>BEGIN
    # Algol 68 allows operator overloading, both of existing operators and new ones  #
    # Programmer defined operators can be a "bold word" (uppercase word) or a symbol #
    # Symbolic operators can be one or two characters, optionally followed by := or  #
    # =:, =: can also be defined as an operator (Allowed in Algol 68G, possibly not  #
    # in other implementations)                                                      #
    # the characters allowed in a symbolic operator depends on the implementation    #
    # but would include +, -, *, /, <, =, >                                          #

    # define a new TOSTRING operator and overload it #
    OP TOSTRING = ( INT  n )STRING: whole( n, 0 ); # returns a string representation of n in the minimum width #
    OP TOSTRING = ( BOOL b )STRING: IF b THEN "true" ELSE "false" FI;
    # overide a standard operator #
    INT a = 10, b = 11, c = 21;
    BEGIN
        OP + = ( INT a, INT b )INT: a - b;
        # + between strings is a standard operator that does string concation #
        print( ( TOSTRING a + " ""+"" " + TOSTRING b + " = " + TOSTRING ( a + b ) + " = " + TOSTRING c + "? " + TOSTRING ( ( a + b ) = c )
               , newline
               )
             )
    END;
    # same print, with the stndard + #
    print( ( TOSTRING a + "  +  " + TOSTRING b + " = " + TOSTRING ( a + b ) + " = " + TOSTRING c + "? " + TOSTRING ( ( a + b ) = c )
           , newline
           )
         );
    # overload + to allow a BOOL to be added to an INT #
    OP + = ( INT a, BOOL b )INT: IF b THEN a + 1 ELSE a FI;
    print( ( TOSTRING a + " ""+"" " + TOSTRING ( a = 10 ) + " = " + TOSTRING ( a + ( a = 10 ) ), newline ) )
END</lang>
{{out}}
<pre>
10 "+" 11 = -1 = 21? false
10  +  11 = 21 = 21? true
10 "+" true = 11
</pre>

=={{header|C++}}==
Operator overloading is one of the classic features of C++, but truth be told, I am writing such code after 20 years.......

And yes, I know subtracting cuboids can give negative volumes. It's theoretically possible (remember volume or triple integrals ? ).
<lang cpp>
//Aamrun, 4th October 2021

#include <iostream>
using namespace std;

class Cuboid {
   
   private:
      double length;    
      double breadth;    
      double height;    
   
   public:
      double getVolume(void) {
         return length * breadth * height;
      }
      void setLength( double l ) {
         length = l;
      }
      void setBreadth( double b ) {
         breadth = b;
      }
      void setHeight( double h ) {
         height = h;
      }
      

      Cuboid operator +(const Cuboid& c) {
         Cuboid biggerCuboid;
         biggerCuboid.length = this->length + c.length;
         biggerCuboid.breadth = this->breadth + c.breadth;
         biggerCuboid.height = this->height + c.height;
         return biggerCuboid;
      }
      
      Cuboid operator -(const Cuboid& c) {
         Cuboid smallerCuboid;
         smallerCuboid.length = this->length - c.length;
         smallerCuboid.breadth = this->breadth - c.breadth;
         smallerCuboid.height = this->height - c.height;
         return smallerCuboid;
      }
};

int main() {
   Cuboid c1;               
   Cuboid c2;               
   Cuboid c3;               
   double volume = 0.0;    

   c1.setLength(6.0); 
   c1.setBreadth(7.0); 
   c1.setHeight(5.0);
 
   c2.setLength(12.0); 
   c2.setBreadth(13.0); 
   c2.setHeight(10.0);
 
   volume = c1.getVolume();
   std::cout << "Volume of 1st cuboid : " << volume <<endl;
 
   volume = c2.getVolume();
   std::cout << "Volume of 2nd cuboid : " << volume <<endl;

   //Adding the two cuboids
   c3 = c1 + c2;

   volume = c3.getVolume();
   std::cout << "Volume of 3rd cuboid after adding : " << volume <<endl;
   
   //Subtracting the two cuboids
   c3 = c1 - c2;

   volume = c3.getVolume();
   std::cout << "Volume of 3rd cuboid after subtracting : " << volume <<endl;

   return 0;
}
</lang>
{{out}}
<pre>
Volume of 1st cuboid : 210
Volume of 2nd cuboid : 1560
Volume of 3rd cuboid after adding : 5400
Volume of 3rd cuboid after subtracting : -180
</pre>

=={{header|F_Sharp|F#}}==
For those who complain that they can't follow my F# examples perhaps if I do the following it will help them.
<lang fsharp>
// Overloaded operators. Nigel Galloway: September 16th., 2021
let (+) (n:int) (g:int) = n-g
printfn "%d" (23+7)
</lang>
{{out}}
<pre>
16
</pre>

=={{header|jq}}==
{{works with|jq}}
'''Works with gojq, the Go implementation of jq'''

Many of jq's built-in operators are "overloaded" in the sense that they
can be used on more than one built-in jq data type, these being: "null", "boolean", "string", "object"
and "array".

The prime example of an overloaded operator in jq is `+`, which is defined on:
<pre>
null x ANY # additive zero
ANY x null # additive zero
number x number # addition
array x array  # concatenation
object x object # coalesence
</pre>

Note that `+` is symmetric except for its restriction to object x object, as illustrated by:
<lang jq>{"a":1} + {"a": 2} #=> {"a": 2}

{"a":2} + {"a": 1} #=> {"a": 1}</lang>
Most of the other operators that are usually thought of as "arithmetic" are also overloaded, notably:
<pre>
-: array x array  # e.g. [1,2,1] - [1] #=> [2]
*: string x number # e.g. "a" * 3   #=> "aaa"
/: string x string # e.g. "a/b/c" / "/"' #=> ["a","b","c"]
</pre>

The comparison operators (<, <=, ==, >=, >) are defined for all JSON entities and thus
can be thought of as being overloaded, but this is only because jq defines a total order on JSON entities.

The comparison operators can also be used on non-JSON entities as well, e.g.
<lang jq>
0 < infinite #=> true
nan < 0 #=> true
</lang>

The logical operators (`and`, `or`, `not`) are also defined for all JSON entities, their logic being
based on the idea that the only "falsey" values are `false` and `null`.

Whether a function (meaning a given name/arity pair) is "overloaded" or not depends entirely on its definition,
it being understood that jq functions with the same name but different arities can have entirely unrelated definitions.

`length/0` is defined on all JSON entities except `true` and `false`.  Note that it is defined
as the absolute value on JSON numbers, and that:
<lang jq>nan|length #=> null</lang>

It is also worth pointing out that a single name/arity function can have multiple definitions within
a single program, but normal scoping rules apply so that in any one context, only one definition is
directly accessible.  The functionality of the "outer" definition, however, can be accessed indirectly,
as illustrated by the following contrived example:
<lang jq>def foo:
  def outer_length: length;
  def length: outer_length | tostring;
  [outer_length, length];

"x" | foo #=> [1, "1"]</lang>

=={{header|Julia}}==
Most operators in Julia's base syntax are in fact just syntactic sugar for function calls. In particular, the symbols:
<lang julia>
* / ÷ % & ⋅ ∘ × ∩ ∧ ⊗ ⊘ ⊙ ⊚ ⊛ ⊠ ⊡ ⊓ ∗ ∙ ∤ ⅋ ≀ ⊼ ⋄ ⋆ ⋇ ⋉ ⋊ ⋋ ⋌ ⋏ ⋒ ⟑ ⦸ ⦼ ⦾ ⦿ ⧶ ⧷ ⨇ ⨰ ⨱ ⨲ ⨳ ⨴ ⨵ ⨶ ⨷ ⨸ ⨻
⨼ ⨽ ⩀ ⩃ ⩄ ⩋ ⩍ ⩎ ⩑ ⩓ ⩕ ⩘ ⩚ ⩜ ⩞ ⩟ ⩠ ⫛ ⊍ ▷ ⨝ ⟕ ⟖ ⟗ 
</lang>
are parsed in the same precedence as the multiplication operator function *, and the symbols:
<lang julia>
+ - ⊕ ⊖ ⊞ ⊟ ∪ ∨ ⊔ ± ∓ ∔ ∸ ≏ ⊎ ⊻ ⊽ ⋎ ⋓ ⧺ ⧻ ⨈ ⨢ ⨣ ⨤ ⨥ ⨦ ⨧ ⨨ ⨩ ⨪ ⨫ ⨬ ⨭ ⨮ ⨹ ⨺ ⩁ ⩂ ⩅ ⩊ ⩌ ⩏ ⩐ ⩒ ⩔ ⩖ ⩗ ⩛ ⩝ ⩡ ⩢ ⩣
</lang>
are parsed as infix operators with the same precedence as +. There are many other operator symbols that can be used as prefix or as infix operators once defined as a function in Julia.
<br /><br />
As a language, much of Julia is organized around the concept of multiple dispatch. Because the language dispatches function calls according to the types of the function arguments, even the base arthmetic operators are in fact overloaded operators in Julia.
For example,<lang julia>2 * 3</lang> is sent to the function *(x::Int, y::Int)::Int, whereas <lang julia>2.0 * 3.0</lang>
is dispatched to the overloaded function *(x::Float64, y::Float64)::Float64. Similarly, string concatenation in Julia is with * rather than +, so "hello " * "world" is dispatched to the overloaded function *(x::String, y::String)::String, and other types such as matrices also have arithmetic operators overloaded in base Julia:
<lang julia>julia> x = [1 2; 3 4]; y = [50 60; 70 80]; x + y
2×2 Matrix{Int64}:
 51  62
 73  84
</lang>
Users may define their own overloaded functions in similar ways, whether or not such operators are already used in base Julia. In general, it is considered bad practice, as "operator piracy," to define a user overloaded operator which dispatches on the same types for which base Julia has already defined the same function. Instead, user defined types can be best made to have analogous operators defined for
the new type so as to leverage existing code made for analagous base types. This can allow generic functions to use new types in efficient and constructive ways.

=={{header|Nim}}==
Nim allows overloading of operators. There is no restrictions regarding types of arguments when overloading an operator. For instance, we may define a vector type and addition of vectors:

<lang Nim>type Vector = tuple[x, y, z: float]

func `+`(a, b: Vector): Vector = (a.x + b.x, a.y + b.y, a.z + b.z)

echo (1.0, 2.0, 3.0) + (4.0, 5.0, 6.0)  # print (x: 5.0, y: 7.0, z: 9.0)</lang>

The list of predefined operators with their precedence can be found here: https://rosettacode.org/wiki/Operator_precedence#Nim

Nim allows also user defined operators which must be composed using the following characters:

=     +     -     *     /     <     >
@     $     ~     &     %     |
!     ?     ^     .     :     \

For instance, we may define an operator <code>^^</code> the following way:

<lang Nim>func `^^`(a, b: int): int = a * a + b * b</lang>

To determine the precedence of user-defined operators, Nim defines a set of rules:

Unary operators always bind stronger than any binary operator: <code>$a + b</code> is <code>($a) + b</code> and not <code>$(a + b)</code>.

If an unary operator's first character is <code>@</code> it is a sigil-like operator which binds stronger than a primarySuffix: <code>@x.abc</code> is parsed as <code>(@x).abc</code> whereas <code>$x.abc</code> is parsed as <code>$(x.abc)</code>.

For binary operators that are not keywords, the precedence is determined by the following rules:

Operators ending in either <code>-></code>, <code>~></code> or <code>=></code> are called arrow like, and have the lowest precedence of all operators.

If the operator ends with <code>=</code> and its first character is none of <code><</code>, <code>></code>, <code>!</code>, <code>=</code>, <code>~</code>, <code>?</code>, it is an assignment operator which has the second-lowest precedence.

Otherwise, precedence is determined by the first character.

=={{header|Phix}}==
Phix does not allow operator overloading and it is not possible to define new operators.<br>
<small>(Fairly weak arguments for, pretty strong against, any few minutes saved typing something in the first time are almost always lost the first time it needs to be maintained, if you want my opinion)</small>

The standard arithmetic operators accept (mixed) integer and floating point values without casting.

The relational operators accept integer, float, string, and sequence values.

The logical operators only accept atoms, however there are 40-something sq_xxx() builtins that can be used<br>
to perform all the builtin operations on any mix of integer, float, string, or sequence values.

Subscripts and concatenation work equivalently on strings and sequences, and in fact concatenation on integers and floats.

Any parameter can be integer, float, string, or sequence if it is declared as an object.

For example printf() can accept [a file number, format string and] a single atom or a sequence of objects, <br>
it being wise to wrap lone strings in {} to ensure you get the whole thing not just the first letter.

Inline assembly mnemonics have multiple implicit addressing modes as per the standard intel syntax.

<!--<lang Phix>(phixonline)-->
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%g\n"</span><span style="color: #0000FF;">,</span><span style="color: #000000;">3.5</span> <span style="color: #0000FF;">+</span> <span style="color: #000000;">3</span><span style="color: #0000FF;">)</span>                <span style="color: #000080;font-style:italic;">-- 6.5</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%t\n"</span><span style="color: #0000FF;">,</span><span style="color: #000000;">3.5</span> <span style="color: #0000FF;">></span> <span style="color: #000000;">3</span><span style="color: #0000FF;">)</span>                <span style="color: #000080;font-style:italic;">-- true</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%t\n"</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"a"</span> <span style="color: #0000FF;">=</span> <span style="color: #008000;">"a"</span><span style="color: #0000FF;">)</span>              <span style="color: #000080;font-style:italic;">-- true</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%t\n"</span><span style="color: #0000FF;">,{</span><span style="color: #000000;">1</span><span style="color: #0000FF;">}</span> <span style="color: #0000FF;">=</span> <span style="color: #0000FF;">{</span><span style="color: #000000;">2</span><span style="color: #0000FF;">})</span>              <span style="color: #000080;font-style:italic;">-- false</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%V\n"</span><span style="color: #0000FF;">,{{</span><span style="color: #000000;">1</span><span style="color: #0000FF;">}</span> <span style="color: #0000FF;">&</span> <span style="color: #0000FF;">{</span><span style="color: #000000;">2</span><span style="color: #0000FF;">}})</span>            <span style="color: #000080;font-style:italic;">-- {1,2}</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%V\n"</span><span style="color: #0000FF;">,{</span><span style="color: #000000;">1</span> <span style="color: #0000FF;">&</span> <span style="color: #000000;">2.3</span><span style="color: #0000FF;">})  </span>            <span style="color: #000080;font-style:italic;">-- {1,2.3}</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%V\n"</span><span style="color: #0000FF;">,{</span><span style="color: #008000;">"a"</span> <span style="color: #0000FF;">&</span> <span style="color: #008000;">"b"</span><span style="color: #0000FF;">})</span>            <span style="color: #000080;font-style:italic;">-- "ab"</span>
 <span style="color: #7060A8;">printf</span><span style="color: #0000FF;">(</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #008000;">"%V\n"</span><span style="color: #0000FF;">,{</span><span style="color: #008000;">"AB"</span><span style="color: #0000FF;">[</span><span style="color: #000000;">2</span><span style="color: #0000FF;">]</span> <span style="color: #0000FF;">&</span> <span style="color: #0000FF;">{</span><span style="color: #000000;">1</span><span style="color: #0000FF;">,</span><span style="color: #000000;">2</span><span style="color: #0000FF;">}[</span><span style="color: #000000;">1</span><span style="color: #0000FF;">]})</span>   <span style="color: #000080;font-style:italic;">-- {66,1}</span>
 
 <span style="color: #004080;">integer</span> <span style="color: #000000;">i</span>
 #ilASM{ lea eax,[i]
         mov [eax],ebx
         mov [i],ebx
         mov [i],0
         mov eax,ebx
         mov eax,1   -- etc
       } 
<!--</lang>-->

=={{header|Raku}}==
While it is very easy to overload operators in Raku, it isn't really common...
at least, not in the traditional sense. Or it's extremely common... It depends on how you view it.

One of the founding principles of Raku is that: "Different things should look different". It follows that "Similar things should look similar".

To pick out one tiny example: Adding numbery things together shouldn't be easily confusable with concatenating
strings. Instead, Raku has the "concatenation" operator: ~ for joining stringy
things together.

Using a numeric-ish operator implies that you want a numeric-ish answer... so Raku
will try very hard to give you what you ask for, no matter what operands you
pass it.

Raku operators have multiple candidates to try to fulfil your request and will
try to coerce the operands to a sensible value.

Addition:
<lang perl6>say  3    +  5;      # Int plus Int
say  3.0  +  0.5e1;  # Rat plus Num
say '3'   +  5;      # Str plus Int
say  3    + '5';     # Int plus Str
say '3'   + '5';     # Str plus Str
say '3.0' + '0.5e1'; # Str plus Str
say (2, 3, 4) + [5, 6]; # List plus Array</lang>

+ is a numeric operator so every thing is evaluated numerically if possible
{{out}}
<pre>8
8
8
8
8
8
5 # a list or array evaluated numerically returns the number of elements</pre>


Concatenation:
<lang perl6>say  3    ~  5;      # Int concatenate Int
say  3.0  ~  0.5e1;  # Rat concatenate Num
say '3'   ~  5;      # Str concatenate Int
say  3    ~ '5';     # Int concatenate Str
say '3'   ~ '5';     # Str concatenate Str
say '3.0' ~ '0.5e1'; # Str concatenate Str
say (2, 3, 4) ~ [5, 6]; # List concatenate Array</lang>

~ is a Stringy operator so everything is evaluated as a string (numerics are evaluated numerically then coerced to a string).
{{out}}
<pre>35
35
35
35
35
3.00.5e1
2 3 45 6 # default stringification, then concatenate</pre>

There is nothing preventing you from overloading or overriding existing
operators. Raku firmly believes in not putting pointless restrictions on
what you can and can not do. Why make it hard to do the "wrong" thing when
we make it so easy to do it right?

There is no real impetus to "overload" existing operators to do ''different''
things, it is '''very''' easy to add new operators in Raku, and nearly '''any'''
Unicode character or combination may used to define it. They may be infix,
prefix, postfix, (or post-circumfix!) The precedence, associativity and arity
are all easily defined. An operator at heart is just a subroutine with funny calling conventions.

Borrowed from the [[Nimber_arithmetic#Raku|Nimber arithmetic]] task: 

New operators, defined in place. Arity is two (almost all infix operators
take two arguments), precedence is set equivalent to similar existing operators,
default (right) associativity. The second, ⊗, actually uses itself to define
itself.

<lang perl6>sub infix:<⊕> (Int $x, Int $y) is equiv(&infix:<+>) { $x +^ $y }

sub infix:<⊗> (Int $x, Int $y) is equiv(&infix:<×>) {
    return $x × $y if so $x|$y < 2;
    my $h = exp $x.lsb, 2;
    return $h ⊗ $y ⊕ (($x ⊕ $h) ⊗ $y) if $x > $h;
    return $y ⊗ $x if $y.lsb < $y.msb;
    return $x × $y unless my $comp = $x.lsb +& $y.lsb;
    $h = exp $comp.lsb, 2;
    (($x +> $h) ⊗ ($y +> $h)) ⊗ (3 +< ($h - 1))
}

say 123 ⊗ 456;</lang>
{{out}}
<pre>31562</pre>


That's all well and good, but suppose you have a new class, say, a Line class, and
you want to be able to do arithmetic on Lines. No need to override the built
in arithmetic operators, just add a multi candidate to do the right thing. A multi
allows ''adding'' a new definition of the operator without disturbing the existing ones. 

Very, '''very''' basic Line class:
<lang perl6>class Line {
    has @.start;
    has @.end;
}

# New infix + multi to add two Lines together, for some bogus definition of add
multi infix:<+> (Line $x, Line $y) {
    Line.new(
       :start(
          sqrt($x.start[0]² + $y.start[0]²),
          sqrt($x.start[1]² + $y.start[1]²)
       ),
       :end(
          sqrt($x.end[0]² + $y.end[0]²),
          sqrt($x.end[1]² + $y.end[1]²)
       )
    )
}

# In operation:
say Line.new(:start(-4,7), :end(5,0)) + Line.new(:start(1,1), :end(2,3));</lang>

{{out}}
<pre>Line.new(start => [4.123105625617661e0, 7.0710678118654755e0], end => [5.385164807134504e0, 3e0])</pre>

To be fair, all of this easy power in a bad programmers hands can lead to incomprehensible code... but bad programmers can be bad in any language.

=={{header|REXX}}==
A lot of the examples were taken from the Raku examples.

The REXX language has the "normal" &nbsp; (as say, compared with PL/I) &nbsp;  overloading of:
* &nbsp; the prefix operators &nbsp; (<big>'''+'''</big> and <big>'''-'''</big>) &nbsp; which are shared with the addition and subtraction operators,
* &nbsp; the multiplication operator &nbsp; (<big>'''*'''</big>) &nbsp; is "shared" with the exponentiation operator &nbsp; (<big>'''**'''</big>),
* &nbsp; the "or" operator &nbsp; (<big>'''|'''</big>) &nbsp; is "shared" with the concatenation operator &nbsp; (<big>'''||'''</big>),
* &nbsp; the "and" operator &nbsp; (<big>'''&'''</big>) &nbsp; is "shared" with the "XOR" (eXclusive OR) operator &nbsp; (<big>'''&&'''</big>), &nbsp; and
* &nbsp; the "negation" operator &nbsp; (<big>'''\'''</big>) &nbsp; is "shared" with the "not" logical comparison operator, &nbsp; as in: &nbsp; &nbsp; &nbsp; <big>''if &nbsp;a\=b&nbsp; then&nbsp; ... </big>'' 

<br>Note that some REXXes may also have other characters (glyphs) for the negation operator &nbsp; (not) &nbsp; such as: &nbsp; &nbsp; <big>^</big> &nbsp; and/or &nbsp; <big>¬</big> &nbsp; glyphs.
<lang rexx>/*REXX pgm shows overloading of some operators: prefix/addition/subtraction/concatenate.*/
say '──positive prefix──'
say  +5                                          /* positive  prefix integer            */
say  + 5                                         /* positive  prefix integer            */
say  ++6                                         /* positive  prefix integer            */
say  ++ 6                                        /* positive  prefix integer            */
say  +++7                                        /* positive  prefix integer            */
say  +++ 7                                       /* positive  prefix integer            */
say  + + + + 8                                   /* positive  prefix integer            */
say  + (9)                                       /* positive  prefix integer            */

say '──negative prefix──'
say  -1                                          /* negative  prefix integer            */
say  - 1                                         /* negative  prefix integer            */
say  --2                                         /* negative  prefix integer            */
say  -- 2                                        /* negative  prefix integer            */
say  ---3                                        /* negative  prefix integer            */
say  --- 3                                       /* negative  prefix integer            */
say  - - - - 4                                   /* negative  prefix integer            */
say  - (9)                                       /* negative  prefix integer            */

say '───addition───'
say  3     +   5                                 /* integer   plus  integer             */
say  3     +   (5)                               /* integer   plus  integer             */
say  3.0   +   0.5e1                             /* rational  plus  number              */
say '3'    +   5                                 /* string    plus  integer             */
say  3     +  ' 5 '                              /* integer   plus  string              */
say  3     +  '5'                                /* integer   plus  string              */
say '3'    +  '5'                                /* string    plus  string              */
say '3'    +  "5"                                /* string    plus  string              */
say '3.0'  +  '0.5e1'                            /* string    plus  string              */

say '──subtraction──'
say  3     -   5                                 /* integer   minus  integer            */
say  3     -   (5)                               /* integer   minus  integer            */
say  3.0   -   0.5e1                             /* rational  minus  number             */
say '3'    -   5                                 /* string    minus  integer            */
say  3     -  '5'                                /* integer   minus  string             */
say  3     -  ' 5 '                              /* integer   minus  string             */
say '3'    -  '5'                                /* string    minus  string             */
say '3'    -  "5"                                /* string    minus  string             */
say '3.0'  -  '0.5e1'                            /* string    minus  string             */

say '──concatenation──'
say  3     ||   5                                /* integer   concatenated  integer     */
say  3     ||   (5)                              /* integer   concatenated  integer     */
say  3.0   ||   0.5e1                            /* rational  concatenated  number      */
say '3'    ||   5                                /* string    concatenated  integer     */
say  3     ||  '5'                               /* integer   concatenated  string      */
say '3'    ||  '5'                               /* string    concatenated  string      */
say "3"    ||  "5"                               /* string    concatenated  string      */
say '3.0'  | | '0.5e1'                           /* string    concatenated  string      */
say  3     ||  ' 5 '.                            /* integer   concatenated  strings     */

say '────abutment────'
say  3          5                                /* integer   abutted  integer          */
say  3          (5)                              /* integer   abutted  integer          */
say  3.0        0.5e1                            /* rational  abutted  number           */
say '3'         5                                /* string    abutted  integer          */
say  3         '5'                               /* integer   abutted  string           */
say '3'        '5'                               /* string    abutted  string           */
say "3"        "5"                               /* string    abutted  string           */
say  3         ' 5 '.                            /* integer   abutted  strings          */

say '──multiplication──'
say  3     *    5                                /* integer   multiplied  integer       */
say  3     *    (5)                              /* integer   multiplied  integer       */
say  3.0   *    0.5e1                            /* rational  multiplied  number        */
say '3'    *    5                                /* string    multiplied  integer       */
say  3     *   '5'                               /* integer   multiplied  string        */
say '3'    *   '5'                               /* string    multiplied  string        */
say "3"    *   "5"                               /* string    multiplied  string        */
say '3.0'  *   '0.5e1'                           /* string    multiplied  string        */

say '──exponentation──'
say  3     **   5                                /* integer  exponetiated integer       */
say  3     **   (5)                              /* integer  exponetiated integer       */
say  3     * *  5                                /* integer  exponetiated integer       */
say  3.0   **   0.5e1                            /* rational exponetiated number        */
say '3'    **   5                                /* string   exponetiated integer       */
say  3     **  '5'                               /* integer  exponetiated string        */
say '3'    **  '5'                               /* string   exponetiated string        */
say "3"    **  "5"                               /* string   exponetiated string        */
say '3.0'  **  '0.5e1'                           /* string   exponetiated string        */

say '────division────'
say  3     /    5                                /* integer  divided  integer           */
say  3     /    (5)                              /* integer  divided  integer           */
say  3.0   /    0.5e1                            /* rational divided  number            */
say '3'    /    5                                /* string   divided  integer           */
say  3     /   '5'                               /* integer  divided  string            */
say '3'    /   '5'                               /* string   divided  string            */
say "3"    /   "5"                               /* string   divided  string            */
say '3.0'  /   '0.5e1'                           /* string   divided  string            */

say '─────not────'
say  \0                                          /* (not)        invert  binary         */
say  \1                                          /* (not)        invert  binary         */
say  \ 1                                         /* (not)        invert  binary         */
say  \ (0)                                       /* (not)        invert  binary         */
say  \ 1                                         /* (not)        invert  binary         */
say  \ (0)                                       /* (not)        invert  binary         */
say  \\ 0                                        /* (not) (not)  invert  binary         */
say  \ \ 1                                       /* (not) (not)  invert  binary         */

say '─────or─────'
say  0     |    0                                /* binary   OR'ed  binary              */
say  0     |    1                                /* binary   OR'ed  binary              */
say '0'    |   "1"                               /* binary   OR'ed  binary              */
say '1'    |    0                                /* binary   OR'ed  binary              */
say '1'    |   (0)                               /* binary   OR'ed  binary              */

say '─────and────'
say  0     &    0                                /* binary   AND'ed  binary             */
say  0     &    1                                /* binary   AND'ed  binary             */
say '0'    &   "1"                               /* binary   AND'ed  binary             */
say '1'    &    0                                /* binary   AND'ed  binary             */
say '1'    &   (0)                               /* binary   AND'ed  binary             */

say '─────XOR────'
say  0     &&    0                               /* binary   XOR'ed  binary             */
say  0     &&    1                               /* binary   XOR'ed  binary             */
say '0'    &&   "1"                              /* binary   XOR'ed  binary             */
say '1'    &&    0                               /* binary   XOR'ed  binary             */
say '1'    &&   (0)                              /* binary   XOR'ed  binary             */

exit 0                                           /*stick a fork in it,  we're all done. */</lang>
{{out|output|text=&nbsp; when using the internal default input:}}
<pre>
──positive prefix──
5
5
6
6
7
7
8
9
──negative prefix──
-1
-1
2
2
-3
-3
4
-9
───addition───
8
8
8.0
8
8
8
8
8
8.0
──subtraction──
-2
-2
-2.0
-2
-2
-2
-2
-2
-2.0
──concatenation──
35
35
3.00.5E1
35
35
35
35
3.00.5e1
3 5 .
────abutment────
3 5
3 5
3.0 0.5E1
3 5
3 5
3 5
3 5
3  5 .
──multiplication──
15
15
15.0
15
15
15
15
15.0
──exponentation──
243
243
243
243
243
243
243
243
243
────division────
0.6
0.6
0.6
0.6
0.6
0.6
0.6
0.6
─────not────
1
0
0
1
0
1
0
1
─────or─────
0
1
1
1
1
─────and────
0
0
0
0
0
─────XOR────
0
1
1
1
1
</pre>

=={{header|Wren}}==
{{libheader|Wren-date}}
<br>
All of Wren's operators can be overloaded except: &&, ||, ?: and =. It is not possible to create new operators from scratch.

When an operator is overloaded it retains the same arity, precedence and associativity as it has when used in its 'natural' sense.

The standard library contains several instances of overloading the '''+''' and '''*''' operators which are demonstrated below.

Otherwise, operator overloading can be used without restriction in user defined classes.

However, whilst it is very useful for classes representing mathematical objects, it should otherwise be used sparingly as code can become unreadable if it is used inappropriately.
<lang ecmascript>import "/date" for Date

var s1 = "Rosetta "
var s2 = "code"
var s3 = s1 + s2          // + operator used to concatenate two strings
System.print("s3 = %(s3)")

var s4 = "a" * 20         // * operator used to provide string repetition
System.print("s4 = %(s4)")

var l1 = [1, 2, 3] + [4]  // + operator used to concatenate two lists
System.print("l1 = %(l1)")

var l2 = ["a"] * 8        // * operator used to create a new list by repeating another
System.print("l2 = %(l2)")

// the user defined class Date overloads the - operator to provide the interval between two dates
var d1 = Date.new(2021, 9, 11)
var d2 = Date.new(2021, 9, 13)
var i1 = (d2 - d1).days
System.print("i1 = %(i1) days")</lang>

{{out}}
<pre>
s3 = Rosetta code
s4 = aaaaaaaaaaaaaaaaaaaa
l1 = [1, 2, 3, 4]
l2 = [a, a, a, a, a, a, a, a]
i1 = 2 days
</pre>