Transportation problem

Transportation problem is to find the optimal transportation plan certain volumes of resources from suppliers to consumers, taking into account the cost of transportation. The plan is a table (matrix), whose rows and columns correspond to the suppliers and consumers, the cells are placed in cargo volume.

Example of the transportation problem:

	Consumer 1, need 20 kg	Consumer 2, need 30 kg	Consumer 3, need 10 kg
Supplier 1, supply 25 kg	$3 per kg	$5 per kg	$7 per kg
Supplier 2, supply 35 kg	$3 per kg	$2 per kg	$5 per kg

For the first time this problem mathematically studied the Soviet mathematician A. N. Tolstoy. In 1930 he published his work on finding the minimum total mileage in rail transportation, which used the redistributive cycles. The main contribution to the development of the mathematical apparatus of the transport problem introduced Soviet economist L. V. Kantorovich during the Great Patriotic War (published in 1939 and 1942). The way to solve the transportation problem by the potential method was it published in conjunction with M. K. Gavurin in 1949.

The program is to solve the classical transport problem using the method of potentials (with redistributive cycle) with the preparation of the initial transportation plan by the north-west corner of the features to be implemented in this task. The input is the number of suppliers and customers, inventory levels, needs and cost matrix transport cargo. The output of the program is the optimal plan. If necessary, enter a fictitious vendor or customer.

The solution for the above example would be the plan:

	Consumer 1	Consumer 2	Consumer 3
Supplier 1	20 kg	-	5 kg
Supplier 2	-	30 kg	5 kg

Glagol

<lang>ОТДЕЛ Транспорт+; ИСПОЛЬЗУЕТ

 Вывод ИЗ "...\Отделы\Обмен\",
 Приём;

ПЕР

 Поставщиков, Потребителей: ЦЕЛ;
 Запасы, Потребности: ДОСТУП К РЯД ИЗ ЦЕЛ;
 Расходы, План: ДОСТУП К РЯД ИЗ РЯД ИЗ ЦЕЛ;
 U, V: ДОСТУП К РЯД ИЗ ЦЕЛ;
 оцСв: ДОСТУП К РЯД ИЗ НАБОР значение: ЦЕЛ; поставщик, потребитель: ЦЕЛ КОН;
 начQ_поставщик, начQ_потребитель: ЦЕЛ;
 Q: ДОСТУП К РЯД ИЗ РЯД ИЗ УЗКЦЕЛ;
 Поправка, Разница: ЦЕЛ;

ЗАДАЧА ПринятьДанные; ПЕР

 сч1, сч2: ЦЕЛ;
 сумма1, сумма2, разница: ЦЕЛ;
 памЗап, памПотр: ДОСТУП К РЯД ИЗ ЦЕЛ;

УКАЗ

 Вывод.Цепь("Number of suppliers: ");
 Поставщиков := Приём.Число();
 Вывод.Цепь(".^Number of consumers: ");
 Потребителей := Приём.Число();
 СОЗДАТЬ(памЗап, Поставщиков);
 СОЗДАТЬ(памПотр, Потребителей);
 Вывод.Цепь(".^Inventories^^");
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   памЗап[сч1] := Приём.Число();
   Вывод.Цепь(" ")
 КОН;
 Вывод.Цепь("^Requirements:^");
 ОТ сч1 := 0 ДО Потребителей-1 ВЫП
   памПотр[сч1] := Приём.Число();
   Вывод.Цепь(" ")
 КОН;
 сумма1 := 0;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП УВЕЛИЧИТЬ(сумма1, памЗап[сч1]) КОН;
 сумма2 := 0;
 ОТ сч1 := 0 ДО Потребителей-1 ВЫП УВЕЛИЧИТЬ(сумма2, памПотр[сч1]) КОН;
 ЕСЛИ сумма1 > сумма2 ТО
   разница := сумма1 - сумма2;
   Вывод.ЧЦел("^Introduced a fictitious consumer.", сумма1, сумма2, разница, 0);
   УВЕЛИЧИТЬ(Потребителей);
   СОЗДАТЬ(Потребности, Потребителей);
   ОТ сч1 := 0 ДО Потребителей-2 ВЫП Потребности[сч1] := памПотр[сч1] КОН;
   Потребности[Потребителей-1] := разница;
   СОЗДАТЬ(Запасы, Поставщиков);
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП Запасы[сч1] := памЗап[сч1] КОН
 АЕСЛИ сумма2 > сумма1 ТО
   разница := сумма2 - сумма1;
   Вывод.ЧЦел("^Introduced a fictitious supplier.", сумма2, сумма1, разница, 0);
   УВЕЛИЧИТЬ(Поставщиков);
   СОЗДАТЬ(Запасы, Поставщиков);
   ОТ сч1 := 0 ДО Поставщиков-2 ВЫП Запасы[сч1] := памЗап[сч1] КОН;
   Запасы[Поставщиков-1] := разница;
   СОЗДАТЬ(Потребности, Потребителей);
   ОТ сч1 := 0 ДО Потребителей-1 ВЫП Потребности[сч1] := памПотр[сч1] КОН
 ИНАЧЕ
   СОЗДАТЬ(Запасы, Поставщиков);
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП Запасы[сч1] := памЗап[сч1] КОН;
   СОЗДАТЬ(Потребности, Потребителей);
   ОТ сч1 := 0 ДО Потребителей-1 ВЫП Потребности[сч1] := памПотр[сч1] КОН
 КОН;
 СОЗДАТЬ(Расходы, Поставщиков, Потребителей);
 Вывод.Цепь("^The matrix of costs:^");
 ЕСЛИ сумма1 > сумма2 ТО
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-2 ВЫП
       Расходы[сч1, сч2] := Приём.Число();
       Вывод.Цепь(" ")
     КОН;
     Расходы[сч1, Потребителей-1] := 0;
     Вывод.Цепь("^")
   КОН
 АЕСЛИ сумма2 > сумма1 ТО
   ОТ сч1 := 0 ДО Поставщиков-2 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       Расходы[сч1, сч2] := Приём.Число();
       Вывод.Цепь(" ")
     КОН;
     Вывод.Цепь("^")
   КОН;
   ОТ сч1 := 0 ДО Потребителей-1 ВЫП Расходы[Поставщиков-1, сч1] := 0 КОН
 ИНАЧЕ
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       Расходы[сч1, сч2] := Приём.Число();
       Вывод.Цепь(" ")
     КОН;
     Вывод.Цепь("^")
   КОН
 КОН;
 СОЗДАТЬ(План, Поставщиков, Потребителей);
 СОЗДАТЬ(U, Поставщиков);
 СОЗДАТЬ(V, Потребителей);
 СОЗДАТЬ(оцСв, Потребителей*Поставщиков-(Потребителей+Поставщиков-1));
 СОЗДАТЬ(Q, Поставщиков, Потребителей)

КОН ПринятьДанные;

ЗАДАЧА ВывестиПлан(); ПЕР

 сч1, сч2: ЦЕЛ;

УКАЗ

 ОТ сч1 := 1 ДО Потребителей ВЫП Вывод.Цепь("-----") КОН;
 Вывод.Цепь("^");
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ План[сч1, сч2] = -1 ТО Вывод.Цепь("  -  ") ИНАЧЕ
       Вывод.ЧЦел("%4d ", План[сч1, сч2], 0, 0, 0);
     КОН
   КОН;
   Вывод.Цепь("^")
 КОН;
 ОТ сч1 := 1 ДО Потребителей ВЫП Вывод.Цепь("-----") КОН

КОН ВывестиПлан;

ЗАДАЧА ПосчитатьПоправку(); ПЕР

 сч1, сч2: ЦЕЛ;

УКАЗ

 Поправка := -1;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ План[сч1, сч2] # -1 ТО
       ЕСЛИ Q[сч1, сч2] = -1 ТО
         ЕСЛИ Поправка = -1 ТО Поправка := План[сч1, сч2]
         АЕСЛИ Поправка > План[сч1, сч2] ТО Поправка := План[сч1, сч2] КОН
       КОН
     КОН
   КОН
 КОН;
 Разница := Разница * Поправка

КОН ПосчитатьПоправку;

ЗАДАЧА РасставитьНули(недостаток: ЦЕЛ); ПЕР

 Связь: ДОСТУП К РЯД ИЗ РЯД ИЗ УЗКЦЕЛ;
 сч1, сч2: ЦЕЛ;
 естьБезСвязи: КЛЮЧ;

 ЗАДАЧА ЕстьНапротив(строка, столбец: ЦЕЛ): КЛЮЧ;
 ПЕР сч: ЦЕЛ;
 УКАЗ
   ОТ сч := 0 ДО Поставщиков-1 ВЫП
     ЕСЛИ (сч # строка) И (Связь[сч, столбец] = 1) ТО ВОЗВРАТ ВКЛ КОН
   КОН;
   ОТ сч := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ (сч # столбец) И (Связь[строка, сч] = 1) ТО ВОЗВРАТ ВКЛ КОН
   КОН;
   ВОЗВРАТ ОТКЛ
 КОН ЕстьНапротив;

 ЗАДАЧА СтолбецБезСвязи(номер: ЦЕЛ): КЛЮЧ;
 ПЕР сч: ЦЕЛ;
 УКАЗ
   ОТ сч := 0 ДО Поставщиков-1 ВЫП
     ЕСЛИ Связь[сч, номер] = 1 ТО ВОЗВРАТ ОТКЛ КОН
   КОН;
   ВОЗВРАТ ВКЛ
 КОН СтолбецБезСвязи;

УКАЗ

 СОЗДАТЬ(Связь, Поставщиков, Потребителей);
 естьБезСвязи := ОТКЛ;
 ОТ сч1 := 0 ДО Потребителей-1 ВЫП
   ЕСЛИ План[0, сч1] = -1 ТО Связь[0, сч1] := -1 ИНАЧЕ Связь[0, сч1] := 1 КОН
 КОН;
 ОТ сч1 := 1 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ План[сч1, сч2] = -1 ТО Связь[сч1, сч2] := -1 ИНАЧЕ Связь[сч1, сч2] := 0 КОН
   КОН
 КОН;
 ОТ сч1 := 1 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ Связь[сч1, сч2] = 0 ТО
       ЕСЛИ ЕстьНапротив(сч1, сч2) ТО Связь[сч1, сч2] := 1
       АЕСЛИ НЕ естьБезСвязи ТО естьБезСвязи := ВКЛ КОН
     КОН
   КОН
 КОН;
 ЕСЛИ естьБезСвязи ТО
   ОТ сч1 := Поставщиков-1 ДО 1 ПО -1 ВЫП
     ОТ сч2 := Потребителей-1 ДО 0 ПО -1 ВЫП
       ЕСЛИ Связь[сч1, сч2] = 0 ТО
         ЕСЛИ ЕстьНапротив(сч1, сч2) ТО Связь[сч1, сч2] := 1
         АЕСЛИ НЕ естьБезСвязи ТО естьБезСвязи := ВКЛ КОН
       КОН
     КОН
   КОН
 КОН;
 ЕСЛИ естьБезСвязи ТО
   ОТ сч1 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ СтолбецБезСвязи(сч1) ТО План[0, сч1] := 0; УМЕНЬШИТЬ(недостаток) КОН;
     ЕСЛИ недостаток = 0 ТО сч1 := Потребителей КОН
   КОН
 КОН;
 КОЛЬЦО
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ недостаток = 0 ТО ВЫХОД ИНАЧЕ
         ЕСЛИ План[сч1, сч2] = -1 ТО
           План[сч1, сч2] := 0; УМЕНЬШИТЬ(недостаток);
         КОН
       КОН
     КОН
   КОН;
   ВЫХОД
 КОН

КОН РасставитьНули;

ЗАДАЧА ЗаполнитьОтУгла; ПЕР

 ОсталосьВНаличии, ОсталосьПотребным: ДОСТУП К РЯД ИЗ ЦЕЛ;
 занято, недостаток: ЦЕЛ;
 сч1, сч2: ЦЕЛ;

УКАЗ

 СОЗДАТЬ(ОсталосьВНаличии, Поставщиков);
 СОЗДАТЬ(ОсталосьПотребным, Потребителей);
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП ОсталосьВНаличии[сч1] := Запасы[сч1] КОН;
 ОТ сч1 := 0 ДО Потребителей-1 ВЫП ОсталосьПотребным[сч1] := Потребности[сч1] КОН;
 занято := 0;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ ОсталосьВНаличии[сч1] = 0 ТО План[сч1, сч2] := -1 ИНАЧЕ
       ЕСЛИ ОсталосьВНаличии[сч1] > ОсталосьПотребным[сч2] ТО
         ЕСЛИ ОсталосьПотребным[сч2] # 0 ТО План[сч1, сч2] := ОсталосьПотребным[сч2]; УВЕЛИЧИТЬ(занято)
         ИНАЧЕ План[сч1, сч2] := -1 КОН;
         УМЕНЬШИТЬ(ОсталосьВНаличии[сч1], ОсталосьПотребным[сч2]);
         ОсталосьПотребным[сч2] := 0
       ИНАЧЕ
         ЕСЛИ ОсталосьВНаличии[сч1] # 0 ТО План[сч1, сч2] := ОсталосьВНаличии[сч1]; УВЕЛИЧИТЬ(занято)
         ИНАЧЕ План[сч1, сч2] := -1 КОН;
         УМЕНЬШИТЬ(ОсталосьПотребным[сч2], ОсталосьВНаличии[сч1]);
         ОсталосьВНаличии[сч1] := 0
       КОН
     КОН
   КОН
 КОН;
 недостаток := (Поставщиков+Потребителей-1) - занято;
 ЕСЛИ недостаток > 0 ТО РасставитьНули(недостаток) КОН

КОН ЗаполнитьОтУгла;

ЗАДАЧА ОценитьБазисныеКлетки; ПЕР

 сч1, сч2, сч3: ЦЕЛ;
 суммы: ДОСТУП К РЯД ИЗ РЯД 3 ИЗ ЦЕЛ;
 известно: ДОСТУП К РЯД ИЗ РЯД 2 ИЗ КЛЮЧ;

УКАЗ

 СОЗДАТЬ(суммы, Поставщиков+Потребителей-1);
 СОЗДАТЬ(известно, Поставщиков+Потребителей-1);
 известно[0][0] := ВКЛ; известно[0][1] := ОТКЛ;
 ОТ сч1 := 1 ДО (Поставщиков+Потребителей-1)-1 ВЫП известно[сч1][0] := ОТКЛ; известно[сч1][1] := ОТКЛ КОН;
 сч3 := 0;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ План[сч1, сч2] # -1 ТО
       суммы[сч3][0] := сч1; суммы[сч3][1] := сч2; суммы[сч3][2] := Расходы[сч1, сч2];
       УВЕЛИЧИТЬ(сч3)
     КОН
   КОН
 КОН;
 U[0] := 0;
 ОТ сч1 := 1 ДО (Поставщиков+Потребителей-1)-1 ВЫП
   ЕСЛИ суммы[сч1][0] = 0 ТО известно[сч1][0] := ВКЛ КОН
 КОН;
 сч3 := 0;
 ПОВТОРЯТЬ
   сч1 := 0;
   ПОКА НЕ (известно[сч1][0] # известно[сч1][1]) ВЫП
     УВЕЛИЧИТЬ(сч1)
   КОН;
   ЕСЛИ известно[сч1][0] ТО
     V[суммы[сч1][1]] := суммы[сч1][2] - U[суммы[сч1][0]];
     известно[сч1][1] := ВКЛ;
     ОТ сч2 := 0 ДО (Поставщиков+Потребителей-1)-1 ВЫП
       ЕСЛИ (суммы[сч2][1] = суммы[сч1][1]) И (НЕ известно[сч2][1]) ТО известно[сч2][1] := ВКЛ КОН
     КОН
   ИНАЧЕ
     U[суммы[сч1][0]] := суммы[сч1][2] - V[суммы[сч1][1]];
     известно[сч1][0] := ВКЛ;
     ОТ сч2 := 0 ДО (Поставщиков+Потребителей-1)-1 ВЫП
       ЕСЛИ (суммы[сч2][0] = суммы[сч1][0]) И (НЕ известно[сч2][0]) ТО известно[сч2][0] := ВКЛ КОН
     КОН
   КОН;
   УВЕЛИЧИТЬ(сч3)
 ДО сч3 = Поставщиков+Потребителей-1

КОН ОценитьБазисныеКлетки;

ЗАДАЧА ОценитьСвободныеКлетки(): КЛЮЧ; ПЕР

 сч1, сч2, сч3: ЦЕЛ;
 естьПолож: КЛЮЧ;

УКАЗ

 естьПолож := ОТКЛ;
 сч3 := 0;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ План[сч1, сч2] = -1 ТО
       оцСв[сч3].значение := U[сч1]+V[сч2]-Расходы[сч1,сч2];
       оцСв[сч3].поставщик := сч1; оцСв[сч3].потребитель := сч2;
       ЕСЛИ оцСв[сч3].значение > 0 ТО естьПолож := ВКЛ КОН;
       УВЕЛИЧИТЬ(сч3)
     КОН
   КОН
 КОН;
 ЕСЛИ естьПолож ТО ВОЗВРАТ ОТКЛ ИНАЧЕ ВОЗВРАТ ВКЛ КОН

КОН ОценитьСвободныеКлетки;

ЗАДАЧА Цикл(); ПЕР

 сч1, сч2, сч3: ЦЕЛ;
 максЗн: ЦЕЛ;
 начало, циклНайден: КЛЮЧ;

 ЗАДАЧА НаЛинии(наКакой: ЦЕЛ; столб: КЛЮЧ): ЦЕЛ;
 ПЕР сч, сколько: ЦЕЛ;
 УКАЗ
   сколько := 0;
   ЕСЛИ столб ТО
     ОТ сч := 0 ДО Поставщиков-1 ВЫП
       ЕСЛИ (План[сч, наКакой] # -1) ИЛИ ((сч = начQ_поставщик) И (наКакой = начQ_потребитель)) ТО
         УВЕЛИЧИТЬ(сколько)
       КОН
     КОН
   ИНАЧЕ
     ОТ сч := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ (План[наКакой, сч] # -1) ИЛИ ((наКакой = начQ_поставщик) И (сч = начQ_потребитель)) ТО
         УВЕЛИЧИТЬ(сколько)
       КОН
     КОН
   КОН;
   ВОЗВРАТ сколько
 КОН НаЛинии;

 ЗАДАЧА^ ИскатьВСтолбце(номер, строка: ЦЕЛ): КЛЮЧ;

 ЗАДАЧА ИскатьВСтроке(номер, столбец: ЦЕЛ): КЛЮЧ;
 ПЕР
   сч: ЦЕЛ;
 УКАЗ
   ЕСЛИ (НЕ начало) И (номер = начQ_поставщик) И (столбец = начQ_потребитель) ТО циклНайден := ВКЛ КОН;
   ЕСЛИ начало ТО начало := ОТКЛ КОН;
   ЕСЛИ циклНайден ТО ВОЗВРАТ ВКЛ КОН;
   ОТ сч := 0 ДО Потребителей-1 ВЫП
     ЕСЛИ
       (сч # столбец) И
       ((План[номер, сч] # -1) ИЛИ ((номер = начQ_поставщик) И (сч = начQ_потребитель))) И
       (НаЛинии(сч, ВКЛ) > 1) И
       (Q[номер, сч] = 0)
     ТО
       Q[номер, сч] := -1;
       ЕСЛИ НЕ ИскатьВСтолбце(сч, номер) ТО Q[номер, сч] := 0 ИНАЧЕ ВОЗВРАТ ВКЛ КОН
     КОН
   КОН;
   ВОЗВРАТ ОТКЛ
 КОН ИскатьВСтроке;

 ЗАДАЧА ИскатьВСтолбце(номер, строка: ЦЕЛ): КЛЮЧ;
 ПЕР
   сч: ЦЕЛ;
 УКАЗ
   ЕСЛИ (НЕ начало) И (строка = начQ_поставщик) И (номер = начQ_потребитель) ТО циклНайден := ВКЛ КОН;
   ЕСЛИ начало ТО начало := ОТКЛ КОН;
   ЕСЛИ циклНайден ТО ВОЗВРАТ ВКЛ КОН;
   ОТ сч := 0 ДО Поставщиков-1 ВЫП
     ЕСЛИ
       (сч # строка) И
       ((План[сч, номер] # -1) ИЛИ ((сч = начQ_поставщик) И (номер = начQ_потребитель))) И
       (НаЛинии(сч, ОТКЛ) > 1) И
       (Q[сч, номер] = 0)
     ТО
       Q[сч, номер] := 1;
       ЕСЛИ НЕ ИскатьВСтроке(сч, номер) ТО Q[сч, номер] := 0 ИНАЧЕ ВОЗВРАТ ВКЛ КОН
     КОН
   КОН;
   ВОЗВРАТ ОТКЛ
 КОН ИскатьВСтолбце;

УКАЗ

 максЗн := 0;
 ОТ сч1 := 0 ДО Потребителей*Поставщиков-(Потребителей+Поставщиков-1)-1 ВЫП
   ЕСЛИ оцСв[сч1].значение > максЗн ТО максЗн := оцСв[сч1].значение КОН
 КОН;
 сч3 := 0;
 ПОКА оцСв[сч3].значение # максЗн ВЫП УВЕЛИЧИТЬ(сч3) КОН;
 ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
   ОТ сч2 := 0 ДО Потребителей-1 ВЫП
     Q[сч1, сч2] := 0
   КОН
 КОН;
 Разница := оцСв[сч3].значение;
 начQ_поставщик := оцСв[сч3].поставщик; начQ_потребитель := оцСв[сч3].потребитель;
 начало := ВКЛ; циклНайден := ОТКЛ;
 ЕСЛИ ИскатьВСтроке(начQ_поставщик, начQ_потребитель) ТО КОН

КОН Цикл;

ЗАДАЧА ИзменитьПлан; ПЕР

 сч1, сч2: ЦЕЛ;
 занято, недостаток: ЦЕЛ;

УКАЗ

 ЕСЛИ Поправка = 0 ТО
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ План[сч1, сч2] = 0 ТО План[сч1, сч2] := -1; сч2 := Потребителей; сч1 := Поставщиков КОН
     КОН
   КОН;
   План[начQ_поставщик, начQ_потребитель] := 0
 ИНАЧЕ
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ Q[сч1, сч2] = 1 ТО
         ЕСЛИ План[сч1, сч2] = -1 ТО План[сч1, сч2] := 0 КОН;
         УВЕЛИЧИТЬ(План[сч1, сч2], Поправка);
       АЕСЛИ Q[сч1, сч2] = -1 ТО УМЕНЬШИТЬ(План[сч1, сч2], Поправка)
       КОН
     КОН
   КОН;
   занято := 0;
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ План[сч1, сч2] > 0 ТО УВЕЛИЧИТЬ(занято) КОН
     КОН
   КОН;
   ОТ сч1 := 0 ДО Поставщиков-1 ВЫП
     ОТ сч2 := 0 ДО Потребителей-1 ВЫП
       ЕСЛИ План[сч1, сч2] = 0 ТО План[сч1, сч2] := -1 КОН
     КОН
   КОН;
   недостаток := (Поставщиков+Потребителей-1) - занято;
   ЕСЛИ недостаток > 0 ТО РасставитьНули(недостаток) КОН
 КОН

КОН ИзменитьПлан;

УКАЗ

 ПринятьДанные;
 ЗаполнитьОтУгла;
 Разница := -1;
 КОЛЬЦО
   ОценитьБазисныеКлетки;
   ЕСЛИ ОценитьСвободныеКлетки() ТО ВЫХОД КОН;
   Цикл;
   ПосчитатьПоправку;
   ИзменитьПлан
 КОН;
 ВывестиПлан

КОН Транспорт.</lang>

Input

Number of suppliers: 3.
Number of consumers: 3.
Inventories:
12 40 33
Requirements:
20 30 10
Introduced a fictitious consumer.
The matrix of costs:
3 5 7
2 4 6
9 1 8

Output

--------------------
  -    -    -    12
  20   -    10   10
  -    30   -     3
--------------------