Imaginary base numbers
Imaginary base numbers are a non-standard positional numeral system which uses an imaginary number as its radix. The most common is quater-imaginary with radix 2i. The quater-imaginary numeral system was first proposed by Donald Knuth in 1955 as a submission for a high school science talent search. [Ref.]
Other imaginary bases are possible too but are not as widely discussed and aren't named.
Task: Write a set of procedures (functions, subroutines, however they are referred to in your language) to convert base 10 numbers to imaginary and back. At a minimum, support quater-imaginary (base 2i).
See Wikipedia: Quater-imaginary_base for more details.
For reference, here are some some decimal and complex numbers converted to quater-imaginary.
|
|
|
|
Perl 6
These are generalized imaginary-base conversion routines. They only work for imaginary bases, not complex. (Any real portion of the radix must be zero.) Theoretically they could be made to work for any imaginary base; in practice, they are limited to integer bases from -6i to -2i and 2i to 6i since those bases will fit within standard base 36 digit representations. Bases -1i and 1i exist but require special handling and are not supported. Bases larger than 6i (or -6i) require digits outside of base 36 to express them, so aren't as standardized, are implementation dependent and are not supported here.
<lang perl6>multi sub base ( Real $num, Int $radix where -37 < * < -1, :$precision = -5 ) {
return '0' unless $num; my $value = $num; my $result = ; my $place = 0; my $lower-bound = $radix / (-$radix + 1); my $upper-bound = 1 / (-$radix + 1);
until $lower-bound <= $value < $upper-bound {
$place += 1;
$value = $num / $radix ** $place;
}
while ($value or $place > 0) and $place > $precision {
my $digit = ($radix * $value - $lower-bound).Int;
$value = $value * $radix - $digit;
$result ~= '.' unless $place or $result.contains: '.';
$result ~= $digit == -$radix ??
($digit-1).base(-$radix)~'0' !!
$digit.base(-$radix);
$place -= 1;
}
$result || '0';
}
multi sub base (Numeric $value, Complex $base where *.re == 0 ) {
die "Base $base out of range" unless -6 <= $base.im <= -2 or 2 <= $base.im <= 6; my ($re, $im) = $value.Complex.reals; $re .= &base((-($base.im)²).Int); $im = ($im/($base.im)).&base((-($base.im)²).Int); my ($re-wh, $re-fr, $im-wh, $im-fr); ($re-wh, $re-fr) = $re.split: '.'; ($im-wh, $im-fr) = $im.split: '.'; $_ //= for ($re-wh, $re-fr, $im-wh, $im-fr);
my @whole = do given $re-wh.chars cmp $im-wh.chars {
when Less { flat (flat $re-wh.flip.comb, '0' xx *) Z flat $im-wh.flip.comb }
when More { flat $re-wh.flip.comb Z flat (flat $im-wh.flip.comb, '0' xx $re-wh.chars - $im-wh.chars) }
default { flat $re-wh.flip.comb Z flat $im-wh.flip.comb }
}
my @fraction = do given $re-fr.chars cmp $im-fr.chars {
when More { flat (flat $im-fr.comb, '0' xx *) Z flat $re-fr.comb }
when Less { flat $im-fr.comb Z flat (flat $re-fr.comb, '0' xx $im-fr.chars - $re-fr.chars) }
default { flat $im-fr.comb Z flat $re-fr.comb }
}
@whole.pop if +@whole and @whole.tail eq '0';
@fraction.pop while +@fraction and @fraction.tail eq '0';
+@fraction ??
@whole.reverse.join ~ '.' ~ @fraction.join !!
@whole.reverse.join
}
multi sub parse-base (Str $str, Complex $radix where *.re == 0) {
return -1 * $str.substr(1).&parse-base($radix) if $str.substr(0,1) eq '-';
my ($whole, $frac) = $str.split: '.';
my $fraction = 0;
$fraction = [+] $frac.comb.kv.map: { $^v.parse-base(($radix.im²).Int) * $radix ** -($^k+1) } if $frac;
$fraction + [+] $whole.flip.comb.kv.map: { $^v.parse-base(($radix.im²).Int) * $radix ** $^k }
}
for 0, 2i, 1, 2i, 5, 2i, -13, 2i, 9i, 2i, -3i, 2i, 7.75-7.5i, 2i, # base 2i
5+5i, 2i, 5+5i, 3i, 5+5i, 4i, 5+5i, 5i, 5+5i, 6i, # same value, positive imaginary bases
5+5i, -2i, 5+5i, -3i, 5+5i, -4i, 5+5i, -5i, 5+5i, -6i, # same value, negative imaginary bases
227.65625+10.859375i, 4i # larger test value
-> $v, $r {
my $ibase = $v.&base($r); printf "%20s.&base\(%2si\) = %-10s : %12s.&parse-base\(%2si\) = %s\n",
$v, $r.im, $ibase, "'$ibase'", $r.im, $ibase.&parse-base($r).round(1e-5);
}</lang>
- Output:
0.&base( 2i) = 0 : '0'.&parse-base( 2i) = 0+0i
1.&base( 2i) = 1 : '1'.&parse-base( 2i) = 1+0i
5.&base( 2i) = 10301 : '10301'.&parse-base( 2i) = 5+0i
-13.&base( 2i) = 1030003 : '1030003'.&parse-base( 2i) = -13+0i
0+9i.&base( 2i) = 103010.2 : '103010.2'.&parse-base( 2i) = 0+9i
-0-3i.&base( 2i) = 1030.2 : '1030.2'.&parse-base( 2i) = 0-3i
7.75-7.5i.&base( 2i) = 11210.31 : '11210.31'.&parse-base( 2i) = 7.75-7.5i
5+5i.&base( 2i) = 10331.2 : '10331.2'.&parse-base( 2i) = 5+5i
5+5i.&base( 3i) = 25.3 : '25.3'.&parse-base( 3i) = 5+5i
5+5i.&base( 4i) = 25.C : '25.C'.&parse-base( 4i) = 5+5i
5+5i.&base( 5i) = 15 : '15'.&parse-base( 5i) = 5+5i
5+5i.&base( 6i) = 15.6 : '15.6'.&parse-base( 6i) = 5+5i
5+5i.&base(-2i) = 11321.2 : '11321.2'.&parse-base(-2i) = 5+5i
5+5i.&base(-3i) = 1085.6 : '1085.6'.&parse-base(-3i) = 5+5i
5+5i.&base(-4i) = 10F5.4 : '10F5.4'.&parse-base(-4i) = 5+5i
5+5i.&base(-5i) = 10O5 : '10O5'.&parse-base(-5i) = 5+5i
5+5i.&base(-6i) = 5.U : '5.U'.&parse-base(-6i) = 5+5i
227.65625+10.859375i.&base( 4i) = 10234.5678 : '10234.5678'.&parse-base( 4i) = 227.65625+10.85937i