Blum integer

A positive integer n is a Blum integer if n = p x q is a semi-prime for which p and q are distinct primes congruent to 3 mod 4. In other words, p and q must be of the form 4t + 3 where t is some non-negative integer.

Blum integer is a draft programming task. It is not yet considered ready to be promoted as a complete task, for reasons that should be found in its talk page.

Definition

Example

21 is a Blum integer because it has two prime factors: 3 (= 4 x 0 + 3) and 7 (= 4 x 1 + 3).

Task

Find and show on this page the first 50 Blum integers.

Also show the 26,828th.

Stretch

Find and show the 100,000th, 200,000th, 300,000th and 400,000th Blum integers.

For the first 400,000 Blum integers, show the percentage distribution by final decimal digit (to 3 decimal places). Clearly, such integers can only end in 1, 3, 7 or 9.

Related task

• Semiprime

References

• Wikipedia article Blum integer
• OEIS sequence A016105: Blum integers

Wren

Library: Wren-math

Library: Wren-fmt

import "./math" for Int
import "./fmt" for Fmt

var blum = []
var bc = 0
var counts = { 1: 0, 3: 0, 7: 0, 9: 0 }
var i = 1
while (true) {
    var f = Int.primeFactors(i)
    if (f.count == 2 && f[0] != f[1] && f[0] % 4 == 3 && f[1] % 4 == 3) {
        blum.add(i)
        counts[i % 10] = counts[i % 10] + 1
        bc = bc + 1
        if (bc == 50) {
            System.print("First 50 Blum integers:")
            Fmt.tprint("$3d ", blum, 10)
            System.print()
        } else if (bc == 26828 || bc % 1e5 == 0) {
            Fmt.print("The $,9r Blum integer is: $,9d", bc, i)
            if (bc == 400000) {
                System.print("\n\% distribution of the first 400,000 Blum integers:")
                for (i in [1, 3, 7, 9]) {
                    Fmt.print("  $6.3f\% end in $i ", counts[i]/4000, i)
                }
                return
            }
        }
    }
    i = (i % 5 == 3) ? i + 4 : i + 2
}

Output:

First 50 Blum integers:
 21   33   57   69   77   93  129  133  141  161 
177  201  209  213  217  237  249  253  301  309 
321  329  341  381  393  413  417  437  453  469 
473  489  497  501  517  537  553  573  581  589 
597  633  649  669  681  713  717  721  737  749 

The  26,828th Blum integer is:   524,273
The 100,000th Blum integer is: 2,075,217
The 200,000th Blum integer is: 4,275,533
The 300,000th Blum integer is: 6,521,629
The 400,000th Blum integer is: 8,802,377

% distribution of the first 400,000 Blum integers:
  25.001% end in 1 
  25.017% end in 3 
  24.997% end in 7 
  24.985% end in 9