Stable marriage problem: Difference between revisions
m
Moved Bracmat below BBC Basic
(Kotlin version updated) |
m (Moved Bracmat below BBC Basic) |
||
Line 383:
STABILITY = FALSE.
eve and hal would rather be together than their current partners.</pre>
=={{header|BBC BASIC}}==
Line 556 ⟶ 473:
Relationships are unstable.
</pre>
=={{header|Bracmat}}==
<lang bracmat>( (abe.abi eve cath ivy jan dee fay bea hope gay)
(bob.cath hope abi dee eve fay bea jan ivy gay)
(col.hope eve abi dee bea fay ivy gay cath jan)
(dan.ivy fay dee gay hope eve jan bea cath abi)
(ed.jan dee bea cath fay eve abi ivy hope gay)
(fred.bea abi dee gay eve ivy cath jan hope fay)
(gav.gay eve ivy bea cath abi dee hope jan fay)
(hal.abi eve hope fay ivy cath jan bea gay dee)
(ian.hope cath dee gay bea abi fay ivy jan eve)
(jon.abi fay jan gay eve bea dee cath ivy hope)
: ?Mplan
: ?M
& (abi.bob fred jon gav ian abe dan ed col hal)
(bea.bob abe col fred gav dan ian ed jon hal)
(cath.fred bob ed gav hal col ian abe dan jon)
(dee.fred jon col abe ian hal gav dan bob ed)
(eve.jon hal fred dan abe gav col ed ian bob)
(fay.bob abe ed ian jon dan fred gav col hal)
(gay.jon gav hal fred bob abe col ed dan ian)
(hope.gav jon bob abe ian dan hal ed col fred)
(ivy.ian col hal gav fred bob abe ed jon dan)
(jan.ed hal gav abe bob jon col ian fred dan)
: ?W
& :?engaged
& whl
' ( !Mplan
: ?A
(?m&~(!engaged:? (!m.?) ?).%?w ?ws)
( ?Z
& ( ( ~(!engaged:?a (?m`.!w) ?z)
& (!m.!w) !engaged
| !W:? (!w.? !m ? !m` ?) ?
& !a (!m.!w) !z
)
: ?engaged
|
)
& !Z !A (!m.!ws):?Mplan
)
)
& ( unstable
= m1 m2 w1 w2
. !arg
: ?
(?m1.?w1)
?
(?m2.?w2)
( ?
& ( !M:? (!m1.? !w2 ? !w1 ?) ?
& !W:? (!w2.? !m1 ? !m2 ?) ?
| !M:? (!m2.? !w1 ? !w2 ?) ?
& !W:? (!w1.? !m2 ? !m1 ?) ?
)
)
)
& ( unstable$!engaged&out$unstable
| out$stable
)
& out$!engaged
& !engaged:(?m1.?w1) (?m2.?w2) ?others
& out$(swap !w1 for !w2)
& ( unstable$((!m1.!w2) (!m2.!w1) !others)
& out$unstable
| out$stable
)
);</lang>
{{out}}
<pre>stable
(dan.fay)
(col.dee)
(hal.eve)
(gav.gay)
(fred.bea)
(ed.jan)
(abe.ivy)
(ian.hope)
(bob.cath)
(jon.abi)
swap fay for dee
unstable</pre>
=={{header|C}}==
| |||