Sieve of Pritchard: Difference between revisions
(julia example) |
m (→{{header|Julia}}: type syntax) |
||
Line 54: | Line 54: | ||
members::Set{T} |
members::Set{T} |
||
steplength::Int |
steplength::Int |
||
Wheel( |
Wheel(T) = new{T}(Set(one(T)), 1) |
||
end |
end |
||
Line 70: | Line 70: | ||
""" Pritchard sieve of primes up to limit, uses limit for type of the primes """ |
""" Pritchard sieve of primes up to limit, uses limit for type of the primes """ |
||
function pritchard(limit = 150) |
function pritchard(limit::T = 150) where T <: Integer |
||
wheel = Wheel( |
wheel = Wheel(T) |
||
prime = |
prime = T(2) |
||
primes = |
primes = T[] |
||
while prime * prime <= limit |
while prime * prime <= limit |
||
if wheel.steplength < limit |
if wheel.steplength < limit |
Revision as of 06:53, 27 August 2022
You are encouraged to solve this task according to the task description, using any language you may know.
The Sieve of Pritchard is a modern algorithm for finding prime numbers. It takes many fewer operations than the Sieve of Eratosthenes (better time complexity), at the cost of greater storage requirements (worse space complexity).
Conceptually, it works by constructing a series of "wheels" marked along their circumference with the pattern of primes up to the value of successive primorial numbers (where the Nth primorial is the product of the first N primes). Those wheels are then rolled along the number line, and only the numbers touched by the marks are considered as candidate primes, in contrast to Eratosthenes' sieve in which all the integers in the range start out as candidates. (The Sieve of Pritchard is an example of the "wheel-based optimizations" mentioned in the Eratosthenes task.)
For example, the second-order wheel has size 6 (the product of the first two primes, 2 and 3) and is marked only at the numbers between 1 and 6 that are not multiples of 2 or 3, namely 1 and 5. As this wheel is rolled along the number line, it will pick up only numbers of the form 6k+1 or 6k+5 (that is, n where n mod 6 is in {1,5}). By the time it stops at 30 (2x3x5) it has added only 8 of the numbers between 6 and 30 as candidates for primality, only one of which is actually composite and must be removed (25). In the process it has constructed the next wheel, which will add only nine out of every 30 numbers as it rolls up to 210.
This YouTube video tells a story to help motivate the algorithm's design;this one presents the execution of the algorithm for N=150 in a format that permits single-stepping forward and backward through the run. In that implementation, the list of primes is populated into a sparse global array s such that s[p] contains the next prime after p iff p is itself a prime in the target range; this allows numbers to be removed from consideration quickly without any the copying/shifting that would be required from a normally-packed array.
- Task
Write a program/subprogram that uses the Sieve of Pritchard algorithm to find all primes up to a specified limit. Show the result of running it with a limit of 150.
- Related tasks
- Sieve of Eratosthenes
- Emirp primes
- count in factors
- prime decomposition
- factors of an integer
- extensible prime generator
- primality by trial division
- factors of a Mersenne number
- trial factoring of a Mersenne number
- partition an integer X into N primes
- sequence of primes by Trial Division
J
Implementation:
pritchard=: {{
spokes=. $.,1
primes=. i.0
while. y > #spokes do.
primes=. primes, p=. 2+(}.spokes) i.1 NB. find next prime
rim=. #spokes NB. "length" of "circumference" of wheel
spokes=. (y<.p*rim)$spokes NB. roll next larger wheel
spokes=. 0 ((#~ y>])_1+p*1+i.rim)} spokes NB. remove newly recognized prime from wheel
end.
while. y > p*p do.
primes=. primes, p=. 2+(}.spokes) i.1 NB. find next prime
spokes=. 0 ((#~ y>])_1+p*1+i.rim)} spokes NB. scrub it out of wheel
end.
primes,1+}.,I.spokes
}}
Task example:
pritchard 150
2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97 101 103 107 109 113 127 131 137 139 149
Julia
""" Rosetta Code task rosettacode.org/wiki/Sieve_of_Pritchard """
""" wheel used to assist in Pritchard's modification of sieve of Eratosthenes """
mutable struct Wheel{T <: Integer}
members::Set{T}
steplength::Int
Wheel(T) = new{T}(Set(one(T)), 1)
end
""" extend the whell to mark off numbers which are not prime """
function extend(wheel, limits)
for w in wheel.members
n = w + wheel.steplength
while n <= maximum(limits)
push!(wheel.members, n)
n += wheel.steplength
end
end
wheel.steplength = minimum(limits)
end
""" Pritchard sieve of primes up to limit, uses limit for type of the primes """
function pritchard(limit::T = 150) where T <: Integer
wheel = Wheel(T)
prime = T(2)
primes = T[]
while prime * prime <= limit
if wheel.steplength < limit
extend(wheel, [prime * wheel.steplength, limit])
end
for w in sort!(collect(wheel.members))
delete!(wheel.members, prime * w)
end
push!(primes, prime)
prime = prime == 2 ? 3 : minimum(filter(>(1), wheel.members))
end
if wheel.steplength < limit
extend(wheel, [limit])
end
append!(primes, filter(!=(1), wheel.members))
return sort!(filter(<=(limit), primes))
end
println(pritchard(150))
- Output:
[2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31, 37, 41, 43, 47, 53, 59, 61, 67, 71, 73, 79, 83, 89, 97, 101, 103, 107, 109, 113, 127, 131, 137, 139, 149]
Raku
First, a direct translation of the implementation in the YouTube video:
unit sub MAIN($limit = 150);
my $maxS = 1;
my $length = 2;
my $p = 3;
my @s = ();
while $p*$p <= $limit {
if $length < $limit {
extend-to [$p*$length, $limit].min;
}
delete-multiples-of($p);
$p = next(1);
}
if $length < $limit {
extend-to $limit;
}
# Done, build the list of actual primes from the array
$p = 3;
my @primes = 2, |gather while $p <= $limit {
take $p;
$p = next($p);
};
say @primes;
exit;
sub extend-to($n) {
my $w = 1;
my $x = $length + 1;
while $x <= $n {
append $x;
$w = next($w);
$x = $length + $w;
}
$length = $n;
if $length == $limit {
append $limit+2;
}
}
sub delete-multiples-of($p) {
my $f = $p;
while $p*$f <= $length {
$f = next($f);
}
while $f > 1 {
$f = prev($f);
delete($p*$f);
}
}
sub append($w) {
@s[$maxS-1] = $w;
@s[$w-2] = $maxS;
$maxS = $w;
}
sub next($w) { @s[$w-1]; }
sub prev($w) { @s[$w-2]; }
sub delete($pf) {
my $temp1 = @s[$pf-2];
my $temp2 = @s[$pf-1];
@s[$temp1-1] = $temp2;
@s[($temp2-2)%@s] = $temp1;
}
- Output:
[2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97 101 103 107 109 113 127 131 137 139 149
Then a slightly more Raku-ish implementation based on the description in the Wikipedia article:
unit sub MAIN($limit = 150);
class Wheel {
has $.members is rw;
has $.length is rw;
method extend(*@limits) {
my @members = $.members.keys;
for @members -> $w {
my $n = $w + $.length;
while $n <= @limits.all {
$.members.set($n);
$n += $.length;
}
}
$.length = @limits.min;
}
}
# start with W₀=({1},1)
my $wheel = Wheel.new: :members(SetHash(1)), :length(1);
my $prime = 2;
my @primes = ();
while $prime * $prime <= $limit {
if $wheel.length < $limit {
$wheel.extend($prime*$wheel.length, $limit);
}
for $wheel.members.keys.sort(-*) -> $w {
$wheel.members.unset($prime * $w);
}
@primes.push: $prime;
$prime = $prime == 2 ?? 3 !! $wheel.members.keys.grep(*>1).sort[0];
}
if $wheel.length < $limit {
$wheel.extend($limit);
}
@primes.append: $wheel.members.keys.grep: * != 1;
say @primes.sort;
The only difference in the output is that the result of `.sort` is a list rather than an array, so it's printed in parentheses instead of square brackets:
- Output:
(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97 101 103 107 109 113 127 131 137 139 149)
Wren
import "./sort" for SortedList
import "./fmt" for Fmt
var extend = Fn.new { |W, length, n|
var w = 1
var x = length + 1
while (x <= n) {
W.add(x)
var ix = W.indexOf(w)
w = W[ix+1]
x = length + w
}
}
var deleteMultiples = Fn.new { |W, length, p|
var w = p
while (p * w <= length) {
var ix = W.indexOf(w)
w = W[ix+1]
}
while (w > 1) {
var ix = W.indexOf(w)
w = W[ix-1]
W.remove(p*w)
}
}
var sieveOfPritchard = Fn.new { |N|
if (N < 2) return []
var W = SortedList.fromOne(1)
var Pr = SortedList.fromOne(2)
var k = 1
var length = 2
var p = 3
while (p * p <= N) {
if (length < N) {
var n = N.min(p*length)
extend.call(W, length, n)
length = n
}
deleteMultiples.call(W, length, p)
Pr.add(p)
k = k + 1
p = W[1]
}
if (length < N) extend.call(W, length, N)
return (Pr + W)[1..-1]
}
Fmt.tprint("$3d", sieveOfPritchard.call(150), 7)
- Output:
2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97 101 103 107 109 113 127 131 137 139 149