Fivenum: Difference between revisions
Added Algol 68
(JavaScript added) |
(Added Algol 68) |
||
Line 220:
=={{header|ALGOL 68}}==
{{Trans|11l}}
Includes additionl test cases as in Pearl, Go etc. with adjustment to n4 for odd length array.
<lang algol68>BEGIN # construct an R-style fivenum function #
PROC quicksort = ( REF[]REAL a, INT lb, ub )VOID:
IF ub > lb THEN
# more than one element, so must sort #
INT left := lb;
INT right := ub;
# choosing the middle element of the array as the pivot #
REAL pivot := a[ left + ( ( right + 1 ) - left ) OVER 2 ];
WHILE
WHILE IF left <= ub THEN a[ left ] < pivot ELSE FALSE FI DO left +:= 1 OD;
WHILE IF right >= lb THEN a[ right ] > pivot ELSE FALSE FI DO right -:= 1 OD;
left <= right
DO
REAL t := a[ left ];
a[ left ] := a[ right ];
a[ right ] := t;
left +:= 1;
right -:= 1
OD;
quicksort( a, lb, right );
quicksort( a, left, ub )
FI # quicksort # ;
PROC fivenum = ( []REAL array )[]REAL:
BEGIN
INT n = ( UPB array + 1 ) - LWB array;
[ 1 : n ]REAL x := array[ AT 1 ];
quicksort( x, LWB x, UPB x );
REAL n4 = ( ( ( n + IF ODD n THEN 3 ELSE 2 FI ) / 2 ) / 2 ) ;
[]REAL d = ( 1, n4, ( n + 1 ) / 2, n + 1 - n4, n );
[ 1 : 5 ]REAL sum_array;
FOR e TO 5 DO
INT fl = ENTIER d[ e ];
INT ce = IF fl < d[ e ] THEN 1 + fl ELSE fl FI;
sum_array[ e ] := 0.5 * ( x[ fl ] + x[ ce ] )
OD;
sum_array
END # five num # ;
PROC show = ( []REAL f )VOID:
FOR i FROM LWB f TO UPB f DO print( ( " ", fixed( f[ i ], -14, 8 ) ) ) OD;
show( fivenum( ( 36, 40, 7, 39, 41, 15 ) ) );
print( ( newline ) );
show( fivenum( ( 15, 6, 42, 41, 7, 36, 49, 40, 39, 47, 43 ) ) );
print( ( newline ) );
show( fivenum( ( 0.14082834, 0.09748790, 1.73131507, 0.87636009
, -1.95059594, 0.73438555, -0.03035726, 1.46675970
, -0.74621349, -0.72588772, 0.63905160, 0.61501527
, -0.98983780, -1.00447874, -0.62759469, 0.66206163
, 1.04312009, -0.10305385, 0.75775634, 0.32566578
)
)
)
END</lang>
{{out}}
<pre>
7.00000000 15.00000000 37.50000000 40.00000000 41.00000000
6.00000000 25.50000000 40.00000000 42.50000000 49.00000000
-1.95059594 -0.67674120 0.23324706 0.74607095 1.73131507
</pre>
=={{header|AppleScript}}==
Line 260 ⟶ 322:
{{output}}
<lang applescript>{{6, 25.5, 40, 42.5, 49}, {7, 15, 37.5, 40, 41}, {-1.95059594, -0.676741205, 0.23324706, 0.746070945, 1.73131507}}</lang>
=={{header|Arturo}}==
| |||