Cousin primes: Difference between revisions
Added Forth solution
(→{{header|ALGOL 68}}: Use ALGOL 68-primes) |
(Added Forth solution) |
||
Line 822:
= 967= 971
AMOUNT OF COUSIN PRIME PAIRS= 41</pre>
=={{header|Forth}}==
{{works with|Gforth}}
<lang forth>: prime? ( n -- ? ) here + c@ 0= ;
: not-prime! ( n -- ) here + 1 swap c! ;
: prime-sieve ( n -- )
here over erase
0 not-prime!
1 not-prime!
2
begin
2dup dup * >
while
dup prime? if
2dup dup * do
i not-prime!
dup +loop
then
1+
repeat
2drop ;
: cousin-primes ( n -- )
dup prime-sieve
0
over 4 - 0 do
i prime? if i 4 + prime? if
1+
." (" i 3 .r ." , " i 4 + 3 .r ." )"
dup 5 mod 0= if cr else space then
then then
loop
swap
cr ." Number of cousin prime pairs < " . ." is " . cr ;
1000 cousin-primes
bye</lang>
{{out}}
<pre>
( 3, 7) ( 7, 11) ( 13, 17) ( 19, 23) ( 37, 41)
( 43, 47) ( 67, 71) ( 79, 83) ( 97, 101) (103, 107)
(109, 113) (127, 131) (163, 167) (193, 197) (223, 227)
(229, 233) (277, 281) (307, 311) (313, 317) (349, 353)
(379, 383) (397, 401) (439, 443) (457, 461) (463, 467)
(487, 491) (499, 503) (613, 617) (643, 647) (673, 677)
(739, 743) (757, 761) (769, 773) (823, 827) (853, 857)
(859, 863) (877, 881) (883, 887) (907, 911) (937, 941)
(967, 971)
Number of cousin prime pairs < 1000 is 41
</pre>
=={{header|FreeBASIC}}==
| |||