Concatenate two primes is also prime: Difference between revisions

</pre>

=={{header|PL/M}}==

{{works with|8080 PL/M Compiler}} ... under CP/M (or an emulator)

<syntaxhighlight lang="plm">

100H: /* FIND SOME PAIRS OF PRIMES BETWEEN 1 AND 99 SUCH THAT IF THEIR */

/* DIGITS ARE CONCATENATED, THE RESULT IS ALSO A PRIME */

/* CP/M BDOS SYSTEM CALL AND I/O ROUTINES */

BDOS: PROCEDURE( FN, ARG ); DECLARE FN BYTE, ARG ADDRESS; GOTO 5; END;

PR$CHAR: PROCEDURE( C ); DECLARE C BYTE; CALL BDOS( 2, C ); END;

PR$STRING: PROCEDURE( S ); DECLARE S ADDRESS; CALL BDOS( 9, S ); END;

PR$NL: PROCEDURE; CALL PR$STRING( .( 0DH, 0AH, '$' ) ); END;

PR$NUMBER: PROCEDURE( N );

DECLARE N ADDRESS;

DECLARE V ADDRESS, N$STR( 6 ) BYTE, W BYTE;

V = N;

W = LAST( N$STR );

N$STR( W ) = '$';

N$STR( W := W - 1 ) = '0' + ( V MOD 10 );

DO WHILE( ( V := V / 10 ) > 0 );

N$STR( W := W - 1 ) = '0' + ( V MOD 10 );

END;

CALL PR$STRING( .N$STR( W ) );

END PR$NUMBER;

/* TASK */

DECLARE FALSE LITERALLY '0';

DECLARE TRUE LITERALLY '0FFH';

DECLARE CONCAT$PRIME LITERALLY '0FH';

DECLARE MAX$LOW$PRIME LITERALLY '99';

DECLARE PRIME ( 10$000 )BYTE; /* PRIME SIEVE. A BIT LARGER THN NEEDED */

/* THE FIRST NYBBLE WILL BE SET TO 0 IF */

/* IT IS A CONCATENATED PRIME */

/* THE SIZE OF PRIME SHOULD BE AT LEAST MAX$LOW$PRIME SQUARED */

/* SIEVE THE PRIMES TO MAX$PRIME */

DECLARE ( I, J, COUNT ) ADDRESS;

PRIME( 1 ) = FALSE; PRIME( 2 ) = TRUE;

DO I = 3 TO LAST( PRIME ) BY 2; PRIME( I ) = TRUE; END;

DO I = 4 TO LAST( PRIME ) BY 2; PRIME( I ) = FALSE; END;

DO I = 3 TO MAX$LOW$PRIME + 1;

IF PRIME( I ) THEN DO;

DO J = I * I TO LAST( PRIME ) BY I + I; PRIME( J ) = FALSE; END;

END;

END;

/* FIND THE CONCATEDNATED PRIMES */

COUNT = 0;

DO I = 2 TO MAX$LOW$PRIME;

IF PRIME( I ) THEN DO;

DO J = 2 TO MAX$LOW$PRIME;

IF PRIME( J ) THEN DO;

DECLARE CP ADDRESS;

IF J < 10 THEN CP = I * 10;

ELSE CP = I * 100;

CP = CP + J;

IF PRIME( I ) AND PRIME( J ) AND PRIME( CP ) THEN DO;

/* CP IS A CONCATENATED PRIME - FLAG PRIME( CP ) AS SUCH */

PRIME( CP ) = CONCAT$PRIME;

END;

END;

END;

END;

END;

/* SHOW THE CONCATENATED PRIMES */

/* SINGLE DIGIT NUMBERS CAN'T BE CONCATENATED PRIMES, START AT 10 */

DO I = 3 TO LAST( PRIME ) BY 2;

IF PRIME( I ) = CONCAT$PRIME THEN DO;

/* HAVE A CONCATENATED PRIME */

CALL PR$CHAR( ' ' );

IF I < 1000 THEN DO;

CALL PR$CHAR( ' ' );

IF I < 100 THEN CALL PR$CHAR( ' ' );

END;

CALL PR$NUMBER( I );

IF ( COUNT := COUNT + 1 ) MOD 10 = 0 THEN CALL PR$NL;

END;

END;

EOF

</syntaxhighlight>

{{out}}

<pre>

23 37 53 73 113 137 173 193 197 211

223 229 233 241 271 283 293 311 313 317

331 337 347 353 359 367 373 379 383 389

397 433 523 541 547 571 593 613 617 673

677 719 733 743 761 773 797 977 1117 1123

1129 1153 1171 1319 1361 1367 1373 1723 1741 1747

1753 1759 1783 1789 1913 1931 1973 1979 1997 2311

2341 2347 2371 2383 2389 2917 2953 2971 3119 3137

3167 3719 3761 3767 3779 3797 4111 4129 4153 4159

4337 4373 4397 4723 4729 4759 4783 4789 5323 5347

5923 5953 6113 6131 6143 6173 6197 6719 6737 6761

6779 7129 7159 7331 7919 7937 8311 8317 8329 8353

8389 8923 8929 8941 8971 9719 9743 9767